Ersetzen Sie Linien, die einem Muster entsprechen, durch Linien aus einer anderen Datei in der richtigen Reihenfolge?

Ich möchte die Zeilen, die einem Muster aus einer Datei entsprechen, durch die Zeilen in der Reihenfolge aus einer anderen Datei ersetzen, zum Beispiel gegeben:

Datei1.txt :

aaaaaa
bbbbbb
!! 1234
!! 4567
ccccc
ddddd
!! 1111

Wir ersetzen gerne die Zeilen beginnend mit !! mit den Zeilen dieser Datei:

file2.txt :

first line
second line
third line

das Ergebnis sollte also sein:

aaaaaa
bbbbbb
first line
second line
ccccc
ddddd
third line

Akzeptierte Antwort:

Einfach geht das mit awk

awk '
    /^!!/{                    #for line stared with `!!`
        getline <"file2.txt"  #read 1 line from outer file into $0 
    }
    1                         #alias for `print $0`
    ' file1.txt

Andere Version

awk '
    NR == FNR{         #for lines in first file
        S[NR] = $0     #put line in array `S` with row number as index 
        next           #starts script from the beginning
    }
    /^!!/{             #for line stared with `!!`
        $0=S[++count]  #replace line by corresponded array element
    }
    1                  #alias for `print $0`
    ' file2.txt file1.txt